我們(men) 在學單片機時我們(men) 第一個(ge) 例程就是燈的閃爍，那是用延時程序做的，現在回想起來，這樣做不很恰當，為(wei) 什麽(me) 呢？我們(men) 的主程序做了燈的閃爍，就不能再幹其它的事了，難道單片機隻能這樣工作嗎？當然不是，我們(men) 能用定時器來實現燈的閃爍的功能。

例1：查詢方式

ORG 0000H

AJMP START

ORG 30H

START:

MOV P1,#0FFH ;關(guan) 所 燈

MOV TMOD,#00000001B ;定時/計數器0工作於(yu) 方式1

MOV TH0,#15H

MOV TL0,#0A0H ;即數5536

SETB TR0 ;定時/計數器0開始運行

LOOP:JBC TF0,NEXT ;如果TF0等於(yu) 1，則清TF0並轉NEXT處

AJMP LOOP ;不然跳轉到LOOP處運行

NEXT:CPL P1.0

MOV TH0,#15H

MOV TL0,#9FH;重置定時/計數器的初值

AJMP LOOP

END AJMP LOOP

END

   鍵入程序，看到了什麽(me) ？燈在閃爍了，這可是用定時器做的，不再是主程序的循環了。簡單地分析一下程序，為(wei) 什麽(me) 用JBC呢？TF0是定時/計數器0的溢出標記位，當定時器產(chan) 生溢出後，該位由0變1，所以查詢該位就可知宇時時間是否已到。該位為(wei) 1後，要用軟件將標記位清0，以便下一次定時是間到時該位由0變1，所以用了JBC指令，該指位在判1轉移的同時，還將該位清0。

   以上程序是能實現燈的閃爍了，可是主程序除了讓燈閃爍外，還是不能做其他的事啊！不，不對，我們(men) 能在LOOP：……和AJMP LOOP指令之間插入一些指令來做其他的事情，隻要保證執行這些指令的時間少於(yu) 定時時間就行了。那我們(men) 在用軟件延時程序的時候不是也能用一些指令來替代DJNZ嗎？是的，但是那就要求你精確計算所用指令的時間，然後再減去對應的DJNZ循環次數，很不方便，而現在隻要求所用指令的時間少於(yu) 定時時間就行，顯然要求低了。當然，這樣的辦法還是不好，所以我們(men) 常用以下的辦法來實現。

程序2：用中斷實現

ORG 0000H   ,https://www.51hei.com

AJMP START

ORG 000BH ;定時器0的中斷向量地址

AJMP TIME0 ;跳轉到真正的定時器程序處

ORG 30H

START:

MOV P1,#0FFH ;關(guan) 所 燈

MOV TMOD,#00000001B ;定時/計數器0工作於(yu) 方式1

MOV TH0,#15H

MOV TL0,#0A0H ;即數5536

SETB EA ;開總中斷允許

SETB ET0 ;開定時/計數器0允許

SETB TR0 ;定時/計數器0開始運行

LOOP: AJMP LOOP ;真正工作時,這裏可寫(xie) 任意程序

TIME0: ;定時器0的中斷處理程序

PUSH ACC

PUSH PSW ;將PSW和ACC推入堆棧保護

CPL P1.0

MOV TH0,#15H

MOV TL0,#0A0H ;重置定時常數

POP PSW

POP ACC

RETI

END

    上麵的例程中，定時時間一到，TF0由0變1，就會(hui) 引發中斷，CPU將自動轉至000B處尋找程序並執行，由於(yu) 留給定時器中斷的空間隻有8個(ge) 字節，顯然不足以寫(xie) 下所有有中斷處理程序，所以在000B處安排一條跳轉指令，轉到實際處理中斷的程序處，這樣，中斷程序能寫(xie) 在任意地方，也能寫(xie) 任意長度了。進入定時中斷後，首先要保存當前的一些狀態，程序中隻演示了保存存ACC和PSW，實際工作中應該根據需要將可能會(hui) 改變的單元的值都推入堆棧進行保護（本程序中實際不需保存護任何值，這裏隻作個(ge) 演示）。

   上麵的兩(liang) 個(ge) 單片機程序運行後，我們(men) 發現燈的閃爍非常快，根本分辨不出來，隻是視覺上感到燈有些晃動而已，為(wei) 什麽(me) 呢？我們(men) 能計算一下，定時器中預置的數是5536，所以每計60000個(ge) 脈衝(chong) 就是定時時間到，這60000個(ge) 脈衝(chong) 的時間是多少呢？我們(men) 的晶體(ti) 震蕩器是12M，所以就是60000微秒，即60毫秒，因此速度是非常快的。如果我想實現一個(ge) 1S的定時，該怎麽(me) 辦呢？在該晶體(ti) 震蕩器瀕率下，最長的定時也就是65。536個(ge) 毫秒啊！上麵給出一個(ge) 例程。

ORG 0000H

AJMP START

ORG 000BH ;定時器0的中斷向量地址

AJMP TIME0 ;跳轉到真正的定時器程序處

ORG 30H

START:

MOV P1,#0FFH ;關(guan) 所 燈

MOV 30H,#00H ;軟件計數器預清0

MOV TMOD,#00000001B ;定時/計數器0工作於(yu) 方式1

MOV TH0,#3CH

MOV TL0,#0B0H ;即數15536

SETB EA ;開總中斷允許

SETB ET0 ;開定時/計數器0允許

SETB TR0 ;定時/計數器0開始運行

LOOP: AJMP LOOP ;真正工作時,這裏可寫(xie) 任意程序

TIME0: ;定時器0的中斷處理程序

PUSH ACC

PUSH PSW ;將PSW和ACC推入堆棧保護

INC 30H

MOV A,30H

CJNE A,#20,T_RET ;30H單元中的值到了20了嗎?

T_L1: CPL P1.0 ;到了,取反P10

MOV 30H,#0 ;清軟件計數器

T_RET:

MOV TH0,#15H

MOV TL0,#9FH ;重置定時常數

POP PSW

POP ACC

RETI

END

  先自己分析一下，看看是怎麽(me) 實現的？這裏采用了軟件計數器的概念，思路是這樣的，先用定時/計數器0做一個(ge) 50毫秒的定時器，定時是間到了以後並不是立即取反P10，而是將軟件計數器中的值加1，如果軟件計數器計到了20，就取反P10，並清掉軟件計數器中的值，不然直接返回，這樣，就變成了20次定時中斷才取反一次P10，因此定時時間就延長了成了20*50即1000毫秒了。

   這個(ge) 思路在工程中是非常有用的，有的時候我們(men) 需要若幹個(ge) 定時器，可51中總共才有2個(ge) ，怎麽(me) 辦呢？其實，隻要這幾個(ge) 定時的時間有一定的公約數，我們(men) 就能用軟件定時器加以實現，如我要實現P10口所接燈按1S每次，而P11口所接燈按2S每次閃爍，怎麽(me) 實現呢？對了我們(men) 用兩(liang) 個(ge) 計數器，一個(ge) 在它計到20時，取反P10，並清零，就如上麵所示，另一個(ge) 計到40取反P11，然後清0，不就行了嗎？這部份的程序如下

ORG 0000H 

AJMP START

ORG 000BH ;定時器0的中斷向量地址

AJMP TIME0 ;跳轉到真正的定時器程序處

ORG 30H

START:

MOV P1,#0FFH ;關(guan) 所 燈

MOV 30H,#00H ;軟件計數器預清0

MOV TMOD,#00000001B ;定時/計數器0工作於(yu) 方式1

MOV TH0,#3CH

MOV TL0,#0B0H ;即數15536

SETB EA ;開總中斷允許

SETB ET0 ;開定時/計數器0允許

SETB TR0 ;定時/計數器0開始運行

LOOP: AJMP LOOP ;真正工作時,這裏可寫(xie) 任意程序

TIME0: ;定時器0的中斷處理程序

PUSH ACC

PUSH PSW ;將PSW和ACC推入堆棧保護

INC 30H

INC 31H ;兩(liang) 個(ge) 計數器都加1

MOV A,30H

CJNE A,#20,T_NEXT ;30H單元中的值到了20了嗎?

T_L1: CPL P1.0 ;到了,取反P10

MOV 30H,#0 ;清軟件計數器

T_NEXT:

MOV A,31H

CJNE A,#40,T_RET ;31h單元中的值到40了嗎?

T_L2:

CPL P1.1

MOV 31H,#0 ;到了,取反P11,清計數器,返回

T_RET:

MOV TH0,#15H

MOV TL0,#9FH ;重置定時常數

POP PSW

POP ACC

RETI

END

您能用定時器的辦法實現前麵講的流水燈嗎？試試看。